Autor: Peter Haserodt  --- Aus Excel Standard - Gruppe: Basiswissen

Platzhalter

Autor: Peter Haserodt - Erstellt: ?      - Letzte Revision: ?
Platzhalter - Oder wer hat das Handtuch auf den Liegestuhl geworfen

Es gibt einige Funktionen oder Funktionalitäten die mit Platzhaltern arbeiten.
Aber was ist dies überhaupt?
Wir schauen uns dies anhand der Funktion Zählenwenn an.
Nehmen wir folgende Liste, in welcher ich schon verschiedene Möglichkeiten dargestellt habe und weiter unten erklären werde:
 
 ABCDE
1     
2 Haus 4 
3 Hans 1 
4 Hausen 7 
5 haus 3 
6 Ent?enhausen 8 
7 *Haus 8 
8 *Mann 2 
9 Aha 1 
10     
Formeln der Tabelle
D2 : =ZÄHLENWENN($B$2:$B$9;"Ha*")
D3 : =ZÄHLENWENN($B$2:$B$9;"*Ha")
D4 : =ZÄHLENWENN($B$2:$B$9;"*Ha*")
D5 : =ZÄHLENWENN($B$2:$B$9;"Ha?s")
D6 : =ZÄHLENWENN($B$2:$B$9;"*")
D7 : =ZÄHLENWENN($B$2:$B$9;"**")
D8 : =ZÄHLENWENN($B$2:$B$9;"~**")
D9 : =ZÄHLENWENN($B$2:$B$9;"*~?*")
 


Das Sternchen (*) oft auch als Asterisk bezeichnet (Ne Ne - kein Zaubertrank )

Das Sternchen steht für eine beliebige Zeichenfolge.

In Zelle D2 sehen wir eine mögliche Anwendung: Eine Zeichenfolge mit einem Sternchen endend bedeutet:
Alle Zeichenketten die mit der Zeichenfolge beginnen und danach eine beliebige Zeichenkette haben.

Beachten Sie: Es wird nicht nach Groß -und Kleinschreibung unterschieden!

In Zelle D3 machen wir es umgekehrt - Alle die mit der Zeichenfolge enden und eine beliebige Zeichenkette vornedran haben.

Und in Zelle D4 ist es nun klar - oder? Alle die die Zeichenfolge beinhalten!


Das Fragezeichen (?)

Das Fragezeichen steht genau für ein Zeichen in der Zeichenfolge, ansonsten muss die Zeichenfolge übereinstimmen.

In D5 sehen wir ein Anwendungsbeispiel: Es werden alle Zeichenketten gefunden, die mit Ha beginnen, dann ein beliebiges Zeichen haben und mit einem s enden. Dies trifft auf Hans und Haus zu und auf haus - wir sehen auch hier keine Unterscheidung zwischen Groß- Kleinschreibung.

Selbstverständlich können Sie das Fragezeichen auch mehrmals einsetzen, z.B. H??S würde alles finden, was mit H beginnt - dann 2 beliebige Zeichen hat und mit s endet.

Ihre Meinung zu Online Excel Geben Sie uns ein Feedback
Die Tilde (~) - Wir gehen zum Maskenball!

In den Zellen D6 und D7 sehen Sie die verzweifelte Bemühung, Zeichenketten zu finden, die mit einem Sternchen beginnen. Wir erhalten aber immer alle Einträge! So was blödes

Aber auch dafür gibt es eine Lösung:

Will man Platzhalter selbst in der Suche einsetzen, muss man diese "maskieren"!
Dies kennt man aus vielen Programmiersprachen oder aus anderen Anwendungen. Maskieren bedeutet soviel wie: Nimm das Zeichen als das wie es dasteht und nicht in seiner Bedeutung als Platzhalter.

In Excel ist das Maskierungszeichen die Tilde (~)

Und wie wir dies anwenden können sehen Sie in D8 und D9.

Und beachten Sie: Wollen Sie nach der Tilde selbst suchen dann müssen Sie auch diese maskieren und zwar mit der Tilde.

Bsp:

Um alle Zeichenketten zu finden, die mit einer Tilde beginnen, wäre der Ausdruck:
~~*

Also zweimal die Tilde und dann gefolgt von einem Sternchen für eine beliebige Zeichenkettenfolge.

Noch ein kleiner Hinweis:

Die Onlinehilfe ist hier sehr dürftig und zumindest in Excel XP sogar falsch


Weitere Artikel der Gruppe: Basiswissen Aus Excel Standard
Nach oben
ToDo
Google Werbung