Zeichen zählen leicht gemacht

Es ist relativ einfach, das Vorkommen von Zeichen in einem Text zu zählen.
Man muss nur entscheiden, ob man Groß/Klein beachten will oder nicht.
(Wechseln arbeitet CaseSensitiv)

Zuerst das Beispiel und dann die Erklärung:

A B C D E F 1             2   Online Excel ist perfekt         3             4   Gesucht e E e/E   5   Vorkommen 4 1 5   6             Formeln der Tabelle C5 : =LÄNGE(B2) -LÄNGE( WECHSELN(B2;"e";"")) D5 : =LÄNGE(B2) -LÄNGE( WECHSELN(B2;"E";"")) E5 : =LÄNGE(B2) -LÄNGE( WECHSELN(KLEIN(B2);"e";""))

Wechseln ermöglicht ein Zeichen in einem Text gegen ein anderes zu wechseln.
Wir benutzen einfach den Trick, es gegen ein Leerzeichen zu wechseln.
Im ersten Beispiel ersetzen wir alle e's durch "nichts".
Die Länge des Textes von
Online Excel ist perfekt
ist 24.
Jetzt ersetzen wir e durch nichts und dabei kommt folgendes raus:
Onlin Excl ist prfkt
Dessen Länge ist 20.

24-20 = 4 und schon haben wir die Anzahl der e's im Text.

Im 2.Beispiel das Gleiche für E
Nur das dritte Beispiel benötigt noch etwas Erklärung:

Wenn wir sowohl die e's als auch die E's zählen wollen, können wir wieder einen Trick anwenden.
Wir zählen einfach alle e's und stellen sicher, dass für jedes E im Text ein e erscheint.

Dies machen wir mit der Funktion Klein, die alle Buchstaben des Textes in Kleinbuchstaben umwandelt.

Und wer jetzt sagt, wir hätten doch auch schreiben können:
=LÄNGE(B2) -LÄNGE( WECHSELN(GROSS(B2);"E";""))
Bekommt 100 Zusatzpunkte!

Und dass dies nicht nur für einzelne Zeichen gilt sondern auch für Zeichenketten:

A B C D E F 1             2   Online Excel excelt gut, excelent         3             4   Gesucht excel Excel excel/Excel   5   Vorkommen 2 1 3   6             Formeln der Tabelle C5 : =(LÄNGE(B2) -LÄNGE( WECHSELN(B2;"excel";"")))/LÄNGE("excel") D5 : =(LÄNGE(B2) -LÄNGE( WECHSELN(B2;"Excel";"")))/LÄNGE("Excel") E5 : =(LÄNGE(B2) -LÄNGE( WECHSELN(KLEIN(B2);"excel";"")))/LÄNGE("excel")

Die Begründung hierfür rauszufinden, überlasse ich ihnen!